D:\Mirserver\Mir200\Envir\Market_def 下建立2个NPC文本
D:\Mirserver\Mir200\Envir\Merchant.txt 里加上2个NPC坐标

比如2个NPC 一个叫 天下第一行会-3.txt  一个叫竞标员-3.txt
把以下文字复制到天下第一行会脚本中

(@@InPutString @@InPutInteger )
[@main]
<【行会名称】/SCOLOR=154><$STR(A109)>\
<【竞标时间】/SCOLOR=154><$STR(A110)>\
<【行会掌门】/SCOLOR=154><$STR(A121)>\
<【行会公告】/SCOLOR=154><$STR(A119)>\
<━━━━━━━━━━━━━━━━━━━━━━━━━━━━━/SCOLOR=69>\
<本行会现在公开向全服招贤纳士，欢迎各路英雄豪杰加入到本行会/SCOLOR=250>\
<→/AUTOCOLOR=254,251,168,191,250,70,245,249,253>[<加入该行会/@加入>]<←/AUTOCOLOR=254,251,168,191,250,70,245,249,253>最低等级要求为<$STR(G108)>级\
<━━━━━━━━━━━━━━━━━━━━━━━━━━━━━/SCOLOR=69>\
[<我要竞标/@我也要竞标>]                            [<管理选项/@竞标台管理>]

[@我也要竞标]
<请在边上的竞标员处选择竞标！！/SCOLOR=250>

[@加入]
#if
equal a109 暂无
#act
SENDMSG 6 [非法操作]
goto @main
break
#if
equal g109 1
#act
messagebox 对不起，本行会暂时不收人
break
#IF
HAVEGUILD
#ACT
MESSAGEBOX [失败]:您已经有行会了。无法申请!\请先退出你当前的行会！
break
#if
CHECKLEVELEX < <$STR(g108)>
#act
messagebox 等级不够！
break
#if
#act
AddGuildMember <$STR(A109)> <$USERNAME>
messagebox 恭喜你已经成功加入到<$STR(A109)>
goto @main

[@竞标台管理]
#if
ISGUILDMASTER
equal a109 <$GUILDNAME>
#act
goto @竞标台管理2
#elseact
SENDMSG 5 [只有本行会掌门才可以进行管理]
goto @main

[@竞标台管理2]
#if
equal g109 0
#act
mov s1 <开启/SCOLOR=250>
#if
equal g109 1
#act
mov s1 <关闭>
#if
equal g110 0
#act
mov s2 <允许/SCOLOR=250>
#if
equal g110 1
#act
mov s2 <禁止>
#if
#say
\
→<修改公告内容/@@InPutString11>  当前公告内容:<$STR(A119)>\
→<修改等级要求/@@InPutInteger71>  当前等级要求:<$STR(G108)>级\ \
→<行会收人状态/SCOLOR=254>  当前状态为：<$STR(s1)>  [<更改/@gg1>]\ \
→<返回/@main>


[@gg1]
#if
equal g109 0
#act
mov g109 1
messagebox 行会收人状态→关闭
goto @竞标台管理
break
#if
equal g109 1
#act
mov g109 0
messagebox 行会收人状态→开放
goto @竞标台管理
break



[@InPutInteger71]
#if
large n71 35
small n71 100
#act
mov g108 <$STR(n71)>
messagebox 设定成功，加入你的行会的最低等级要求是<$STR(n71)>级！
goto @竞标台管理
#elseact
messagebox 请输入一个35－100间的整数！
goto @竞标台管理

[@InPutString11]
#if
equal s11
#act
messagebox 非法字符
#elseact
mov a119 <$STR(s11)>
messagebox 修改成功
goto @竞标台管理


把以下这段文字复制到竞标员脚本中

[@main]
【说明】
<土城天下第一行会,可以代替掌门招收会员/SCOLOR=125>\
<竞标方式:采用元宝竞标，只要你给出的价格高于上一个行会的竞/SCOLOR=125>\
<标价格，你的行会就可以中标，直到下一位竞争对手出现./SCOLOR=125>\
<┏━━━━━━━━━━━━━━━━━━━━━━━━━━━┓ /SCOLOR=250>\
<当前竞标行会:/SCOLOR=154> <$STR(A109)>  <竞标价格:/SCOLOR=154> <$STR(G107)> <元宝/SCOLOR=154>\
<竞标时间:/SCOLOR=154> <$STR(A110)>\
<┗━━━━━━━━━━━━━━━━━━━━━━━━━━━┛ /SCOLOR=250>\
[<我要竞标/@竞标开始>]<←只有行会掌门人才可以参与竞标>    [<返回首页/@main>]


[@竞标开始]
#if
ISGUILDMASTER
#act
goto @竞标开始2
#elseact
messagebox 对不起，你不是行会掌门
[@竞标开始2]
#if
equal a109 <$GUILDNAME>
#act
messagebox 错误，你所在的行会已经是中标行会！
break
#elsesay
\ \ \
→<输入竞标价格/@@InPutInteger70> <(只能为整数)>\ \
→<返回/@行会服务>


[@InPutInteger70]
#if
large n70 <$STR(G107)>
#act
goto @竞标3
#elseact
messagebox 对不起，你的出价太低！

[@竞标3]
#if
CHECKGAMEGOLD < <$STR(n70)>
#act
messagebox 对不起，你没有那么多元宝！
#elsesay
你给出的价格为<$STR(n70)>元宝,请填写完整以下信息：\ \
→<输入招收会员的最低等级要求/@@InPutInteger71>  <(35-100)/SCOLOR=253>\
→<输入一段简短公告/@@InPutString11> <(在雕像上显示)/SCOLOR=253>\
<[公告]/SCOLOR=250><$STR(s11)>\ \

→<提交信息/@竞标4>

[@InPutInteger71]
#if
large n71 35
small n71 100
#act
messagebox 设定成功，加入你的行会的最低等级要求是<$STR(n71)>级！
#elseact
messagebox 请输入一个35－100间的整数！
goto @竞标3

[@InPutString11]
#act
goto @竞标3

[@竞标4]
#If
small n71 35
#act
messagebox 请设定招收会员的最低等级要求！
goto @竞标3
#elsesay
<以下是你的全部信息，点击确定提交信息：/SCOLOR=250>\
<行会名称：/SCOLOR=154><$GUILDNAME>\
<行会掌门：/SCOLOR=154><$USERNAME>\
<竞标价格：/SCOLOR=154><$STR(n70)>元宝\
<竞标时间：/SCOLOR=154><$DATETIME>\
<加入该行会的最低等级要求是：/SCOLOR=154><$STR(n71)>级\
<公告内容：/SCOLOR=154><$STR(s11)>\ \

→[<确定提交信息/@竞标5>]              [<返回重新填写/@竞标开始>]


[@竞标5]
#if
CHECKGAMEGOLD > <$STR(n70)>
large n70 <$STR(G107)>
#act
GAMEGOLD - <$STR(n70)>
mov a109 <$GUILDNAME>
mov g107 <$STR(n70)>
mov a110 <$DATETIME>
mov g108 <$STR(n71)>
mov a119 <$STR(s11)>
mov a121 <$USERNAME>
mov g109 0
mov g110 0
SENDMSG 0 [系统]<$USERNAME>为自己的行会竞标成功，该行会的所有成员可以每天领取工资了！
close
#elseact
SENDMSG 7 [超时]
goto @main


这里默认使用元宝竞标，你要改游戏币也可以 ，改荣誉，声望等都行，替换命令就可以了